HelloWorld CMake Demo 03:CMake中构建静态库与动态库及其使用

2014-10-02 20:53:01来源:cnblogs.com作者:GloryOfFamily人点击

 

继续完善Hello World,建立它的共享库, 包括静态库和动态库。

 

本节的任务:

1,建立一个静态库和动态库,提供HelloFunc函数供其他程序编程使用,HelloFunc

向终端输出Hello World字符串。

2,安装头文件与共享库。

3 编写一个程序使用创建的共享库(静态库和动态库)。

 

一,准备工作:

/home/ccj/CMakeDemo目录建立t3目录,用于存放本节涉及到的工程。

cd /home/ccj/CMakeDemo

mkdir t3

 

二,建立共享库

cd /backup/cmake/t3

mkdir lib

 

t3目录下建立CMakeLists.txt,内容如下:

PROJECT(HELLOLIB)

# 通过在主工程文件CMakeLists.txt中修改ADD_SUBDIRECTORY (lib) 指令来指定一个编译输出位置;

# 指定本工程中静态库libhello.so生成的位置,即 build/lib;

ADD_SUBDIRECTORY(lib)

# 也可以通过变更为其他的位置,如

# ADD_SUBDIRECTORY(lib lib_new)

# 则,静态库libhello.so生成的位置变为 build/lib_new;

 

lib目录下建立两个源文件hello.cpp hello.h

hello.cpp内容如下:

#include "hello.h"

using namespace std;

void HelloFunc(){

cout << "Hello World/n";

}

hello.h内容如下:

#ifndef HELLO_H

#define HELLO_H

#include <stdio.h>

void HelloFunc();

#endif

 

lib目录下建立CMakeLists.txt,内容如下:

注意: 这里我们将Section 7之前的CMakeLists.txt中应有的内容提供如下:

SET (LIBHELLO_SRC hello.cpp)

# SET (LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/lib)

 

# three kinds of libraries:

# 1. shared, i.e., dynamic library,动态库文件扩展名常为 "*.so"

# 2. static, i.e., static library 静态库文件扩展名常为 "*.a";

# 而且,我们通常希望静态库和动态库文件名保持一致,只是扩展名不同;

# 3. module, this parameter is valid only when dyld is supported;

# otherwise, will be considered as shared

# 添加动态库,关键词为shared,你不需要写全libhello.so

# 只需要填写hello即可,cmake系统会自动为你生成 libhello.X

ADD_LIBRARY (hello SHARED ${LIBHELLO_SRC})

# 添加静态库,关键词为static

# ADD_LIBRARY (hello STATIC ${LIBHELLO_SRC})

# 仍然用hello作为target名时,是不能成功创建所需的静态库的,

# 因为hello作为一个target是不能重名的, 故把上面的hello修改为hello_static

# 同理,你不需要写全libhello_static.a

# 只需要填写hello即可,cmake系统会自动为你生成 libhello_static.X

ADD_LIBRARY (hello_static STATIC ${LIBHELLO_SRC})

 

# 按照一般的习惯,静态库名字跟动态库名字应该是一致的,只是扩展名不同;

# 即:静态库名为 libhello.a 动态库名为libhello.so

# 所以,希望 "hello_static" 在输出时,不是"hello_static",而是以"hello"的名字显示,故设置如下:

SET_TARGET_PROPERTIES (hello_static PROPERTIES OUTPUT_NAME "hello")

 

GET_TARGET_PROPERTY (OUTPUT_VALUE hello_static OUTPUT_NAME)

MESSAGE (STATUS "This is the hello_static OUTPUT_NAME: " ${OUTPUT_VALUE})

 

# cmake在构建一个新的target时,会尝试清理掉其他使用这个名字的库,

# 因此,在构建libhello.a时,就会清理掉libhello.so.

# 为了回避这个问题,比如再次使用SET_TARGET_PROPERTIES定义 CLEAN_DIRECT_OUTPUT属性。

SET_TARGET_PROPERTIES (hello_static PROPERTIES CLEAN_DIRECT_OUTPUT 1)

SET_TARGET_PROPERTIES (hello PROPERTIES CLEAN_DIRECT_OUTPUT 1)

 

# 按照规则,动态库是应该包含一个版本号的,

# VERSION指代动态库版本,SOVERSION指代API版本。

SET_TARGET_PROPERTIES (hello PROPERTIES VERSION 1.2 SOVERSION 1)

 

# 我们需要将libhello.a, libhello.so.x以及hello.h安装到系统目录,才能真正让其他人开发使用,

# 在本例中我们将hello的共享库安装到<prefix>/lib目录;

# hello.h安装<prefix>/include/hello目录。

INSTALL (TARGETS hello hello_static LIBRARY DESTINATION lib

ARCHIVE DESTINATION lib)

INSTALL (FILES hello.h DESTINATION include/hello)

 

 

三,编译共享库:

仍然采用out-of-source编译的方式,按照习惯,我们建立一个build目录,在build

目录中

cmake ..

make

这时,你就可以在lib目录得到一个libhello.so,这就是我们期望的共享库。

如果你要指定libhello.so生成的位置,可以通过:

  • 在主工程文件CMakeLists.txt中修改ADD_SUBDIRECTORY (lib) 指令来指定一个编译输出位置;
  • 或者在 lib/CMakeLists.txt中添加SET (LIBRARY_OUTPUT_PATH <路径>) 来指定一个新的位置。

 

这两者的区别我们上一节已经提到了,所以,这里不再赘述,下面,我们解释一下一个新的

指令ADD_LIBRARY

 

ADD_LIBRARY(libname [SHARED|STATIC|MODULE]

[EXCLUDE_FROM_ALL] source1 source2 ... sourceN)

你不需要写全 libhello.so,只需要填写hello即可,cmake系统会自动为你生成 libhello.X

 

类型有三种:

  • SHARED,动态库;
  • STATIC,静态库
  • MODULE,在使用dyld的系统有效,如果不支持dyld,则被当作SHARED对待。

 

EXCLUDE_FROM_ALL参数的意思是这个库不会被默认构建,除非有其他的组件依赖或者手动构建。

 

四,添加静态库:

同样使用上面的指令,我们在支持动态库的基础上再为工程添加一个静态库,按照一般的习

惯,静态库名字跟动态库名字应该是一致的,只不过后缀是.a罢了。

下面我们用这个指令再来添加静态库:

 

ADD_LIBRARY(hello STATIC ${LIBHELLO_SRC})

 

然后再在build目录进行外部编译,我们会发现,静态库根本没有被构建,仍然只生成了

一个动态库。因为hello作为一个target是不能重名的,所以,静态库构建指令无效。

如果我们把上面的hello修改为hello_static:

ADD_LIBRARY(hello_static STATIC ${LIBHELLO_SRC})

就可以构建一个libhello_static.a的静态库了。

这种结果显示不是我们想要的,我们需要的是名字相同的静态库和动态库,因为target

称是唯一的,所以,我们肯定不能通过ADD_LIBRARY指令来实现了。这时候我们需要用到

另外一个指令:

SET_TARGET_PROPERTIES

其基本语法是:

SET_TARGET_PROPERTIES (target1 target2 ...PROPERTIES prop1 value1 prop2 value2 ...)

这条指令可以用来设置输出的名称,对于动态库,还可以用来指定动态库版本和API版本。

 

在本例中,我们需要作的是向lib/CMakeLists.txt中添加一条:

SET_TARGET_PROPERTIES(hello_static PROPERTIES OUTPUT_NAME "hello")

这样,我们就可以同时得到libhello.so libhello.a两个库了。

 

SET_TARGET_PROPERTIES对应的指令是:

GET_TARGET_PROPERTY (VAR target property)

 

具体用法如下例,我们向lib/CMakeListst.txt中添加:

GET_TARGET_PROPERTY (OUTPUT_VALUE hello_static OUTPUT_NAME)

MESSAGE(STATUS "This is the hello_static OUTPUT_NAME: "${OUTPUT_VALUE})

如果没有这个属性定义,则返回NOTFOUND.

 

让我们来检查一下最终的构建结果,我们发现,libhello.a已经构建完成,位于

build/lib目录中,但是libhello.so去消失了。这个问题的原因是:cmake在构建一

个新的target时,会尝试清理掉其他使用这个名字的库,因为,在构建libhello.a时,

就会清理掉libhello.so. 为了回避这个问题,比如再次使用SET_TARGET_PROPERTIES定义

CLEAN_DIRECT_OUTPUT属性。

 

lib/CMakeLists.txt中添加:

SET_TARGET_PROPERTIES (hello PROPERTIES CLEAN_DIRECT_OUTPUT 1)

SET_TARGET_PROPERTIES (hello_static PROPERTIES CLEAN_DIRECT_OUTPUT 1)

这时候,我们再次进行构建,会发现build/lib目录中同时生成libhello.solibhello.a了。

 

五,动态库版本号

按照规则,动态库是应该包含一个版本号的,我们可以看一下系统的动态库,一般情况是

libhello.so.1.2

libhello.so ->libhello.so.1

libhello.so.1->libhello.so.1.2

为了实现动态库版本号,我们仍然需要使用SET_TARGET_PROPERTIES指令。

具体使用方法如下:

SET_TARGET_PROPERTIES (hello PROPERTIES VERSION 1.2 SOVERSION 1)

VERSION指代动态库版本,SOVERSION指代API版本。

将上述指令加入lib/CMakeLists.txt中,重新构建看看结果。

build/lib目录会生成:

libhello.so.1.2

libhello.so.1->libhello.so.1.2

libhello.so ->libhello.so.1

 

 

六,安装共享库和头文件

以上面的例子,我们需要将libhello.a, libhello.so.x以及hello.h安装到系统目录,才能真正让其他人开发使用,在本例中我们将hello的共享库安装到<prefix>/lib目录,将hello.h安装<prefix>/include/hello目录。

利用上一节了解到的INSTALL指令,我们向lib/CMakeLists.txt中添加如下指令:

INSTALL (TARGETS hello hello_static LIBRARY DESTINATION lib

ARCHIVE DESTINATION lib)

INSTALL (FILES hello.h DESTINATION include/hello)

注意,静态库要使用ARCHIVE关键字

 

通过:

cmake -DCMAKE_INSTALL_PREFIX=/usr/loal ..

make

sudo make install

我们就可以将头文件和共享库安装到系统目录/usr/local/lib/usr/local/include/hello中了。

如下图:

 

七,编写程序以使用构建好的共享库:

 

前几个sections中,我们已经完成了libhello静、动态库的构建以及安装,本section中我们需要

编写一个程序使用构建好的共享库。

 

1)在~/CMakeDemo/t3/ 目录下建立src目:

并编写源文件main.cpp,内容如下:

#include "hello.h"

int main(){

HelloFunc();

return 0;

}

 

编写工程主文件CMakeLists.txt

PROJECT(NEWHELLO)

ADD_SUBDIRECTORY(src)

 

编写src/CMakeLists.txt

ADD_EXECUTABLE(main main.cpp)

 

2)外部构建

按照习惯,在build目录下,使用cmake ..方式构建。

过程:

cmake ..

make

 

构建失败,如果需要查看细节,可以使用 make VERBOSE=1来构建。

错误结果如下:

错误1

/home/ccj/CMakeDemo/t3/src/main.cpp:1:19: fatal error: hello.h: No such file or directory

#include "hello.h"

 

3)引入头文件搜索路径。

hello.h位于/usr/local/include/hello目录中,并没有位于系统标准的头文件路径里

(有人会说了,白痴啊,你就不会include <hello/hello.h>,同志,要这么干,我这

一节就没什么可写了,只能选择一个glib或者libX11来写了,这些代码写出来很多同志

是看不懂的)

为了让我们的工程能够找到hello.h头文件,我们需要引入一个新的指令

INCLUDE_DIRECTORIES,其完整语法为:

INCLUDE_DIRECTORIES([AFTER|BEFORE] [SYSTEM] dir1 dir2 ...)

这条指令可以用来向工程添加多个特定的头文件搜索路径,路径之间用空格分割,如果路径

中包含了空格,可以使用双引号将它括起来,默认的行为是追加到当前的头文件搜索路径的

后面,你可以通过两种方式来进行控制搜索路径添加的方式:

  • CMAKE_INCLUDE_DIRECTORIES_BEFORE,通过SET这个cmake变量为on,可以将添加的头文件搜索路径放在已有路径的前面。
  • 通过AFTER或者BEFORE参数,也可以控制是追加还是置前。

 

现在我们在src/CMakeLists.txt中添加一个头文件搜索路径,方式很简单,加入:

INCLUDE_DIRECTORIES(/usr/local/include/hello)

 

进入build目录,重新进行构建,这时找不到hello.h的错误已经消失,但是出现了一个新的错误:

 

错误2

CMakeFiles/main.dir/main.o: In function `main':

main.cpp:(.text+0x5): undefined reference to `HelloFunc()'

 

 

因为我们并没有link到共享库libhello上。

 

4target添加共享库

我们现在需要完成的任务是将目标文件链接到libhello,这里我们需要引入两个新的指令

LINK_DIRECTORIES TARGET_LINK_LIBRARIES

LINK_DIRECTORIES的全部语法是:

LINK_DIRECTORIES (directory1 directory2 ...)

这个指令非常简单,添加非标准的共享库搜索路径,比如,在工程内部同时存在共享库和可

执行二进制,在编译时就需要指定一下这些共享库的路径。这个例子中我们没有用到这个指

令。

TARGET_LINK_LIBRARIES的全部语法是:

TARGET_LINK_LIBRARIES(target library1 <debug | optimized> library2 ...)

这个指令可以用来为target添加需要链接的共享库,本例中是一个可执行文件,但是同样可以用于为自己编写的共享库添加共享库链接。

 

为了解决我们前面遇到的"HelloFunc()"未定义错误,我们需要作的是向

src/CMakeLists.txt中添加如下指令:

TARGET_LINK_LIBRARIES(main hello)

 

也可以写成

TARGET_LINK_LIBRARIES(main libhello.so)

这里的hello指的是我们上一节构建的共享库libhello.

 

 

进入build目录重新进行构建。

cmake ..

make

这时我们就得到了一个连接到libhello的可执行程序main,位于build/src目录,

运行main的结果是

让我们来检查一下main的链接情况:

$ ldd src/main

(Note: 虽然show了这个结果,但是没有理解明白,到底链接什么库)

 

 

可以清楚的看到main确实链接了共享库libhello,而且链接的是动态库libhello.so.1

 

那如何链接到静态库呢?

方法很简单:

TARGET_LINK_LIBRRARIES指令修改为:

TARGET_LINK_LIBRARIES(main libhello.a)

重新构建后再来看一下main的链接情况

$ ldd src/main

(Note: 虽然show了这个结果,但是没有理解明白,到底链接什么库)

 

说明,main确实链接到了静态库libhello.a

 

5)特殊的环境变量:CMAKE_INCLUDE_PATH CMAKE_LIBRARY_PATH

 

务必注意CMAKE_INCLUDE_PATH CMAKE_LIBRARY_PATH这两个是环境变量而不是cmake变量。使用方法是要在bash中用export或者在csh中使用set命令设置或者CMAKE_INCLUDE_PATH=/home/include cmake ..等方式。

这两个变量主要是用来解决以前autotools工程中 --extra-include-dir等参数的支持的。

也就是,如果头文件没有存放在常规路径(/usr/include, /usr/local/include),则可以通过这些变量进行弥补。

我们以本例中的hello.h为例,它存放在/usr/include/hello目录,所以直接查找肯定是找不到的。

前面我们直接使用了绝对路径INCLUDE_DIRECTORIES(/usr/local/include/hello)告诉工程这个头文件目录。

为了将提高程序的可移植性,我们可以使用CMAKE_INCLUDE_PATH环境变量来进行,使用bash的方法如下:

export CMAKE_INCLUDE_PATH=/usr/local/include/hello

 

然后在头文件中将INCLUDE_DIRECTORIES(/usr/local/include/hello)替换为:

FIND_PATH(myHeader hello.h)

IF(myHeader)

INCLUDE_DIRECTORIES(${myHeader})

ENDIF(myHeader)

 

上述的一些指令我们在后面会介绍。这里简单说明一下,FIND_PATH用来在指定路径中搜索文件名,比如:FIND_PATH (myHeader NAMES hello.h PATHS /usr/local/include /usr/local/include/hello)

这里我们没有指定路径,但是,cmake仍然可以帮我们找到hello.h存放的路径,就是因

为我们设置了环境变量CMAKE_INCLUDE_PATH

如果你不使用FIND_PATHCMAKE_INCLUDE_PATH变量的设置是不会起作用的,你不能指

望它会直接为编译器命令添加参数-I<CMAKE_INCLUDE_PATH>

 

同理,CMAKE_LIBRARY_PATH可以用在FIND_LIBRARY中。同样,因为这些变量直接为FIND_指令所使用,所以所有使用FIND_指令的cmake模块都会受益。

 

八,小结:

本文中,我们谈到了:

1)创建静、动态库:

  • 如何通过ADD_LIBRARY指令构建动态库和静态库。
  • 如何通过SET_TARGET_PROPERTIES同时构建同名的动态库和静态库。
  • 如何通过SET_TARGET_PROPERTIES控制动态库版本。
  • 使用INSTALL指令来安装头文件和动态、静态库。

2)使用已经构建的共享库libhello和外部头文件:

  • 如何通过INCLUDE_DIRECTORIES指令加入非标准的头文件搜索路径。
  • 如何通过LINK_DIRECTORIES指令加入非标准的库文件搜索路径。
  • 如果通过TARGET_LINK_LIBRARIES为库或可执行二进制加入库链接。
  • 以及解释了如果链接到静态库。

 

到这里为止,您应该基本可以使用cmake工作了,但是还有很多高级的话题没有探讨,比

如编译条件检查、编译器定义、平台判断、如何跟pkgconfig配合使用等等。

到这里,或许你可以理解前面讲到的"cmake的使用过程其实就是学习cmake语言,并编写

cmake程序的过程",既然是"cmake语言",自然涉及到变量、语法等. 下一节,我们将抛开程序的话题,看看常用的CMAKE变量以及一些基本的控制语法规则。

 

 

九,Reference

 

Ref 1. CMake Practice – Cjacker;

微信扫一扫

第七城市微信公众平台